mirror of
https://github.com/wassname/scikit-image.git
synced 2026-06-27 18:25:32 +08:00
Jonathan Helmus
78a0eb6b98
Implement Appveyor builds initial test Updated appveyor.yml New nosetest call With conda update conda with pillow without pillow TST: Change case sensitivive JPG extension Revert "TST: Change case sensitivive JPG extension" This reverts commit 2deed7cc63736f7c6f0387bd37df4c6643c32847. Trying with Python 2.7 Trying with version env Trying again with variables Testing on all Python versions don't allow failures Allow failure Do not actually use tests Ignore failing tests Removed Python 2.6 test Testing only Python 2.6 Testing out more sklearn like AppVeyor CI Added install to pip Add artifacts Enabled all permutations Disable 2.6, add PIL Python 2.6, 2.7 only with PIL Testing with variable dependencies Allow failure with IF ELSE With Python 3.4 Scikit-learn like appveyor CI Fixing paths Undo path fix path fix single line path fix single line 2 Using Miniconda More path fixes New wheelhouse link Added pillow to requirements.txt Added networkx to requirements.txt Add testing of 32/64-bit Python 2.7 and 3.4 to matrix Debugging Cython compile Retry with all 4 builds Updated install.ps1 file Updated based on latest python-appveyor-demo Debugging pip install Specify numpy 1.8.1 until whl is uploaded to rackspace Use skimage-wide requirements.txt file Minor comment change to trigger build Install wheel and then install from WHEELHOUSE Install six from pip Install networkx from pip Install pyparsing from pip Install pytz from pip Try using just find-links Install the binary dependencies first, then the rest Add pillow to the install list Fix appveyor.yml syntax Fix requirements.txt syntax Fix requirements.txt syntax again Fix appveyor call to initial install Fix appveyor call to initial install again Fix appveyor call to initial install yet again Install wheel Install wheel first Install wheel and nose in the appveyor requirements.txt Fix Python3 version to match python ftp site Only use cleanup decorator if available Add debug info to multiimage test More debugging information Fix handling of path separators on Windows Add another warning guard Fix warning handling for non-windows Do not use TkAgg as it may be causing alloc error Clean up echo command Allow for unclosed file warning Fix spacing in echo command
48 lines
1.7 KiB
Batchfile
48 lines
1.7 KiB
Batchfile
:: To build extensions for 64 bit Python 3, we need to configure environment
|
|
:: variables to use the MSVC 2010 C++ compilers from GRMSDKX_EN_DVD.iso of:
|
|
:: MS Windows SDK for Windows 7 and .NET Framework 4 (SDK v7.1)
|
|
::
|
|
:: To build extensions for 64 bit Python 2, we need to configure environment
|
|
:: variables to use the MSVC 2008 C++ compilers from GRMSDKX_EN_DVD.iso of:
|
|
:: MS Windows SDK for Windows 7 and .NET Framework 3.5 (SDK v7.0)
|
|
::
|
|
:: 32 bit builds do not require specific environment configurations.
|
|
::
|
|
:: Note: this script needs to be run with the /E:ON and /V:ON flags for the
|
|
:: cmd interpreter, at least for (SDK v7.0)
|
|
::
|
|
:: More details at:
|
|
:: https://github.com/cython/cython/wiki/64BitCythonExtensionsOnWindows
|
|
:: http://stackoverflow.com/a/13751649/163740
|
|
::
|
|
:: Author: Olivier Grisel
|
|
:: License: BSD 3 clause
|
|
@ECHO OFF
|
|
|
|
SET COMMAND_TO_RUN=%*
|
|
SET WIN_SDK_ROOT=C:\Program Files\Microsoft SDKs\Windows
|
|
|
|
SET MAJOR_PYTHON_VERSION="%PYTHON_VERSION:~0,1%"
|
|
IF %MAJOR_PYTHON_VERSION% == "2" (
|
|
SET WINDOWS_SDK_VERSION="v7.0"
|
|
) ELSE IF %MAJOR_PYTHON_VERSION% == "3" (
|
|
SET WINDOWS_SDK_VERSION="v7.1"
|
|
) ELSE (
|
|
ECHO Unsupported Python version: "%MAJOR_PYTHON_VERSION%"
|
|
EXIT 1
|
|
)
|
|
|
|
IF "%PYTHON_ARCH%"=="64" (
|
|
ECHO Configuring Windows SDK %WINDOWS_SDK_VERSION% for Python %MAJOR_PYTHON_VERSION% on a 64 bit architecture
|
|
SET DISTUTILS_USE_SDK=1
|
|
SET MSSdk=1
|
|
"%WIN_SDK_ROOT%\%WINDOWS_SDK_VERSION%\Setup\WindowsSdkVer.exe" -q -version:%WINDOWS_SDK_VERSION%
|
|
"%WIN_SDK_ROOT%\%WINDOWS_SDK_VERSION%\Bin\SetEnv.cmd" /x64 /release
|
|
ECHO Executing: %COMMAND_TO_RUN%
|
|
call %COMMAND_TO_RUN% || EXIT 1
|
|
) ELSE (
|
|
ECHO Using default MSVC build environment for 32 bit architecture
|
|
ECHO Executing: %COMMAND_TO_RUN%
|
|
call %COMMAND_TO_RUN% || EXIT 1
|
|
)
|